If_Prm_Eqn_Rpt description

fredmarlton

Hi all,

Just wondering if anyone has a good explanation of how If_Prm_Eqn_Rpt works?
I'm not sure if I looked in the right places, but haven't been able to find a description.

Thanks,
Fred

rowlesmr

Hi Fred

You need to read the macro definition in topas.inc in conjunction with the macro preprocessor command definitions in the TechRef

The macro definition is:

macro If_Prm_Eqn_Rpt(c, v, det1, det2)
   {
      #m_ifarg c #m_code
         prm c
         #m_ifarg c #m_code_refine
            #m_ifarg v #m_one_word
               v det1 det2
            #m_else
               v det2
            #m_endif
         #m_else
            #m_first_word v v
         #m_endif
      #m_else
         #m_ifarg c #m_eqn
            prm = c; : #m_first_word v v
         #m_endif
      #m_endif
   }

The translation of that is:

      If c starts with letter or ! and is not an equation
         write "prm c" in the input file
         If c starts with letter and is not an equation
            If v is one word
               write "v det1 det2" in the input file
            otherwise v is more than one word
               write "v det2" in the input file
            endif
         otherwise c must start with !
            write first word of v in the input file
         endif
      otherwise c does not start with a letter or !, or is an equation
         If c is an equation
            write "prm = c; : " and the first word of v in the input file
         endif
      endif

How it is used can be seen through reading topas.inc. It is basically a nice way to set up parameters with default limits.

Anything further from me will have to wait, as my editor is in the process of crashing...

rowlesmr

It lets you do things like:

macro PVII_m(c, v)
   {
      #m_argu c
      If_Prm_Eqn_Rpt(c, v, min .55 max 30, del = 0.05 Val + 0.01; )
      m1 = CeV(c, v);
      m2 = Get(m1);
   }

Here, you call PVII_m(exponent, 4.2), and it will create a parameter with those default limits. If you want to override those limits, you can just call PVII_m(exponent, 4.2 min 2 max 5), and it uses those instead.

fredmarlton

Hi Matthew,

Thanks for the response and information, I think that was exactly what I was after. I'll keep in mind to look in Topas.inc in the future, but it was nice having a more personal explanation, so thanks for putting in the time for that.

Fred